SVR API для непродвинутых

Автор: Александр Терехов
Специально для Королевства Delphi

Вступление...

Предыстория

• ACCESS
• SHARE
• SESSION
• CONNECTION
• FILE
• SERVER
• SECURITY

Функция NetShareAdd

• NetShareAdd - открывает доступ к сетевому ресурсу
• NetShareDel - закрывает доступ к сетевому ресурсу
• NetShareEnum - показывает количество и свойства ресурсов с открытым доступом
• NetShareGetInfo - дает полную информацию об открытом сетевом ресурсе
• NetShareSetInfo - меняет некоторые значения открытого сетевого ресурса

function NetShareAdd(const pszServer: PChar; sLevel: SmallInt; pbBuffer: Pointer;
cbBuffer: Word): NET_API_STATUS; stdcall; 

Подключение внешней функции

Function NetShareAdd(ServerName : PChar; Level : Integer; pbBuffer : Pointer;
BufferSize : Integer) : Integer; stdcall; external 'svrapi.dll'; 

Аргументы функции

Type
    TShareInfo50 = packet record
    shi50_netname: array[0..LM20_NNLEN] of Char; //сетевое имя
    shi50_type: Byte; //тип ресурса
    shi50_flags: Short; //флаг доступа
    shi50_remark: PChar; // комментарий
    shi50_path: PChar; // путь к ресурсу
    shi50_rw_password: array[0..SHPWLEN] of Char;//пароль полного доступа
    shi50_ro_password: array[0..SHPWLEN] of Char;//пароль "только чтение" доступа
    end;

• STYPE_DISKTREE = 0; - будем открывать доступ к директории;
• STYPE_PRINTQ = 1; - будем открывать доступ к принтеру;

• STYPE_DEVICE = 2; - будем открывать доступ к коммуникационному устройству;
• STYPE_IPC = 3; - открывает доступ к межпроцессорной коммуникации.

• SHI50F_RDONLY = $0001; - доступ только на чтение;
• SHI50F_FULL = $0002; - полный доступ;
• SHI50F_DEPENDSON = SHI50F_RDONLY or SHI50F_FULL; - доступ в зависимости от введенного пароля;
• SHI50F_ACCESSMASK = SHI50F_RDONLY or SHI50F_FULL - доступ в зависимости от введенного пароля;
• SHI50F_PERSIST = $0100; - ресурс будет записан в Registry и при перезагрузке компьютера доступ будет открываться в автомате. Для Win'95 почему-то доступ запоминается и без указания этого параметра.
• SHI50F_SYSTEM = $0200; - в проводнике не будет видно, что доступ к этому ресурсу открыт.

1. Если путь указать строчными (маленькими) буквами, то в проводнике не будет видно, что доступ к устройству открыт.
2. Если указать несуществующий путь, то доступ к такому устройству все равно будет открыт. Например, если открыть доступ к несуществующей папке C:TEST333 и присвоить ей сетевое имя TEST66, то в сетевом окружении будет видно сетевое имя TEST66. Если затем создать папку с именем TEST333, то под этой папкой появится "синяя ручка".

Результат функции

NO_ERROR = 0; 'Все в порядке'
(из LmErr.pas):
NERR_BASE = 2100; базовая ошибка для NERR_;
NERR_NetNotStarted = NERR_BASE+2 'Сеть недоступна';
NERR_UnknownServer = NERR_BASE+3 'Неизвестный сервер';
NERR_ServerNotStarted = NERR_BASE+14 'Сервер не работает';
NERR_UnknownDevDir = NERR_BASE+16 'Сетевое устройство отсутствует';
NERR_RedirectedPath = NERR_BASE+17 'Переназначенное устройство';
NERR_DuplicateShare = NERR_BASE+18 'Сетевое имя уже существует';
NERR_BufTooSmall = NERR_BASE+23 'Слишком маленький буфер для данных!';
NERR_NetNameNotFound = NERR_BASE+210 'Сетевое имя не существует';
NERR_InvalidComputer = NERR_BASE+251 'Неверное имя компьютера';
NERR_ShareNotFound = NERR_BASE+292 'Сетевое устройство не обнаружено'.

ERROR_NOT_ENOUGH_MEMORY = 8 'Недостаточно памяти';
ERROR_BAD_NETPATH = 53 'Неверное сетевое имя';
ERROR_NETNAME_DELETED = 64 'Сетевой ресурс более недоступен';
ERROR_NETWORK_ACCESS_DENIED = 65 'Отсутствует доступ к сети';
ERROR_BAD_DEV_TYPE = 66 'Неверный тип сетевого ресурса';
ERROR_BAD_NET_NAME = 67 'Не найдено сетевое имя';
ERROR_INVALID_PARAMETER = 87 'Неверный параметр';
ERROR_INVALID_LEVEL = 124 'Неверный уровень администрирования';

Пример работы NetShareAdd

unit Unit1;
interface
uses
    Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
    StdCtrls ;
type
    TForm1 = class(TForm)
        Button1: TButton;
        Button2: TButton;
        procedure Button1Click(Sender: TObject);
        procedure Button2Click(Sender: TObject);
private
    { Private declarations }
public
    { Public declarations }
end;
//подключаем две функции из библиотеки svrapi.dll
Function NetShareAdd(Servername : PChar; Level : Integer; Buffer : Pointer;
    BufferSize : Integer) : Integer; stdcall; external 'svrapi.dll';
Function NetShareDel(Servername : PChar; NetName : PChar; Reserved:DWORD): DWORD;
    stdcall; external 'svrapi.dll';
//необходимые константы
const
{см. LmCons.pas}
    LM20_NNLEN = 12;
    SHPWLEN = 8;
    SHI50F_RDONLY = 1;
    SHI50F_FULL = 2;
    STYPE_DISKTREE = 0;
    SHI50F_PERSIST = $0100;
    SHI50F_SYSTEM = $0200;
{см. LmErr.pas}
    NERR_BASE = 2100;
    NERR_NetNotStarted = NERR_BASE+2;
    NERR_UnknownServer = NERR_BASE+3;
    NERR_ServerNotStarted = NERR_BASE+14;
    NERR_UnknownDevDir = NERR_BASE+16;
    NERR_RedirectedPath = NERR_BASE+17;
    NERR_DuplicateShare = NERR_BASE+18;
    NERR_BufTooSmall = NERR_BASE+23;
    NERR_NetNameNotFound = NERR_BASE+210;
    NERR_InvalidComputer = NERR_BASE+251;
    NERR_ShareNotFound = NERR_BASE+292;
//формируем тип для записи с необходимыми параметрами
Type
TShareInfo50 = Record
    shi50_netname: Array[0..LM20_NNLEN] Of Char; //сетевое имя
    shi50_type: Byte; //тип ресурса
    shi50_flags: Short; //флаг доступа
    shi50_remark: PChar; // комментарий
    shi50_path: PChar; // путь к ресурсу
    shi50_rw_password: Array[0..SHPWLEN] Of Char;//пароль полного доступа
    shi50_ro_password: Array[0..SHPWLEN] Of Char;//пароль "только чтение" доступа
End; {Record}
var
    Form1: TForm1;
implementation
{$R *.DFM}
 
procedure TForm1.Button1Click(Sender: TObject);
Var
    info50: TShareInfo50;
    rc, cb: Integer;
    ServerName, Path, NetName, ErrMes, ErrCap, Comment:String;
    MessIconBtn:Byte;
begin
//установим необходимые параметры
ServerName:='';
Path:='C:TEMP';
NetName:='TEST';
Comment:='This is a network machine''s commentary';
//заполним буфер
FillChar(info50, sizeof(info50), 0);
With info50 Do
Begin{With}
StrCopy(shi50_netname, PChar(NetName)); //сетевое имя
shi50_type := STYPE_DISKTREE; //подключать будем диск
shi50_remark:=PChar(Comment); //комментарий
shi50_flags:= SHI50F_RDONLY OR SHI50F_FULL //доступ определяется паролем
                    OR SHI50F_PERSIST;//и пишется в Registry
shi50_path:=PChar(Path); //путь
StrPCopy(shi50_rw_password,'ASDF'); //пароль для полного доступа
StrPCopy(shi50_ro_password,'QWE'); // пароль для "только чтение"
End;{With}
//установим размер буфера
cb := sizeof(info50);
//основная функция
rc := NetShareAdd(PChar(ServerName), 50, @info50, cb);
//сформируем текст сообщений об успехе или ошибках
ErrMes:='Доступ к устройству "'+NetName+'" открыт!';
ErrCap:='Все в порядке!';
MessIconBtn:=MB_OK OR MB_ICONINFORMATION;
//проверка ошибок
If rc <> 0 Then
Begin {ошибка}
ErrCap:='Ошибка!';
MessIconBtn:=MB_OK OR MB_ICONERROR;
Case rc Of
//расшифровка ошибок
    ERROR_NOT_ENOUGH_MEMORY : ErrMes:='Недостаточно памяти';
    ERROR_BAD_NETPATH : ErrMes:='"'+Servername+ '" - неверное сетевое имя!';
    ERROR_NETNAME_DELETED : ErrMes:='Сетевой ресурс более недоступен';
    ERROR_NETWORK_ACCESS_DENIED: ErrMes:='Отсутствует доступ к сети';
    ERROR_BAD_DEV_TYPE : ErrMes:='Неверный тип сетевого ресурса';
    ERROR_BAD_NET_NAME : ErrMes:='Не найдено сетевое имя';
    ERROR_INVALID_PARAMETER : ErrMes:='Неверный параметр';
    ERROR_INVALID_LEVEL : ErrMes:='Неверный уровень администрирования';
 
    NERR_InvalidComputer:ErrMes:='Неверное имя компьютера!';
    NERR_UnknownServer:ErrMes:='Неизвестный сервер!';
    NERR_UnknownDevDir:ErrMes:='Устройство "'+Path+'" отсутствует!';
    NERR_ServerNotStarted:ErrMes:='Сервер не работает!';
    NERR_RedirectedPath:ErrMes:='Переназначенный путь!';
    NERR_DuplicateShare:ErrMes:='Сетевое имя "'+NetName+'" уже существует!';
    NERR_BufTooSmall:ErrMes:='Слишком маленький буфер для данных!';
Else
End; {Case}
End; {ошибка}
//выдадим сообщение
MessageBox(Application.Handle,PChar(ErrMes),PChar(ErrCap),MessIconBtn);
end;
 
procedure TForm1.Button2Click(Sender: TObject);
Var
rc:DWord;
Servername,NetName, ErrMes, ErrCap:String;
MessIconBtn:Byte;
begin
ServerName:='';
NetName:='TEST';
rc:=NetShareDel(PChar(ServerName),PChar(NetName),0);
ErrMes:='Доступ к устройству "'+NetName+'" закрыт!';
ErrCap:='Все в порядке!';
MessIconBtn:=MB_OK OR MB_ICONINFORMATION;
 
If rc <> 0 Then
Begin {ошибка}
//ошибка
ErrCap:='Ошибка!';
MessIconBtn:=MB_OK OR MB_ICONERROR;
 
Case rc Of
//расшифровка ошибок
    ERROR_BAD_NETPATH:ErrMes:='"'+Servername+ '" - неверное сетевое имя!';
    ERROR_INVALID_PARAMETER:ErrMes:='Неверный параметр!';
    NERR_NetNotStarted:ErrMes:='Сеть недоступна!';
    NERR_ServerNotStarted:ErrMes:='Сервер не работает!';
    NERR_NetNameNotFound:ErrMes:='Устройство не существует!';
    NERR_ShareNotFound:ErrMes:='Сетевое имя "'+NetName+'" не найдено!';
Else
//смотри ошибки для NetShareAdd или
    ErrMes:='Неизвестная сетевая ошибка!';
End; {Case}
End;{ошибка}
MessageBox(Application.Handle,PChar(ErrMes),PChar(ErrCap),MessIconBtn);
end;
end.

Прилагаемые модули

• SvrAPI.pas - модуль с прототипами Net-функций;
• LmErr.pas - модуль с кодами ошибок;
• LmCons.pas - модуль со значениями констант;
• Examles - пример открытия доступа.

Не забываем, что все, о чем говорилось в этой статье, относится к Win'9x!

SvrAPI для непродвинутых II
или как получить информацию об открытом сетевом ресурсе в Win'9x